ANSYS联轴体的建模与静力学分析实例(附命令流)

本文介绍联轴体的建模以及静力学分析，适合初级入门用户熟悉ANSYS软件GUI操作，学习APDL命令流。

本实例求解联轴体在工作时的应力和形变。联轴体结构如下图所示。

 

联轴体的底面四周的边线不能上下移动（Z方向0位移约束），底面的两个圆其边线上约束所有自由度。

在小轴孔的轴台和小轴孔圆周上加载压力1e6Pa，在大轴孔的轴台和键槽一侧分别加载有压力1e7Pa和1e5Pa。

最后求其变形和应力情况并查看应力动画。

/CLEAR,START            

/FILNAME,lianzouti,0  !jobname 命令为lianzouti,不新建log和error文件

/PREP7  !进入前处理

!**************几何建模****************

CYL4,0,0,5, , , ,10    !创建圆柱体1

CYL4,12,0,3, , , ,4    !创建圆柱体2

LPLOT             !显示线

LOCAL,11,1,0,0,0, , , ,1,1,     !创建11号局部坐标系

K,110,5,-80.4,0,      !在大圆柱体下表面创建点110

K,120,5,80.4,0,      !在大圆柱体下表面创建点120

LOCAL,12,1,12,0,0, , , ,1,1,    !创建12号局部坐标系

K,130,3,-80.4,0,      !在小圆柱体下表面创建点130

K,140,3,80.4,0,       !在小圆柱体下表面创建点140

LSTR,    110,     130 

LSTR,    120,     140 

LSTR,    130,     140 

LSTR,    110,     120  !连接关键点生成直线

/PNUM,LINE,1

/REPLOT         !显示线编号

AL,21,22,23,24    !连接21,22,23,24号线生成面

VOFFST,9,4, ,      !将刚生成的9号面沿面法向拉伸距离4

CSYS,0          !当前坐标系更改为总体笛卡尔坐标系

WPAVE,0,0,8.5    !向Z方向移动工作平面8.5

VSBV,3,1,,,KEEP    !布尔减运算

NUMCMP,VOLU    !压缩体编号

CYL4,0,0,3.5, , , ,1.5 

CYL4,0,0,2.5, , , ,-8.5   !创建大圆柱体内孔

VSBV,1,5

VSBV,6,4            !布尔运算减去内部两个圆柱

NUMCMP,VOLU    !压缩体编号

WPAVE,0,0,0      !偏移工作平面至原点

BLOCK,0,-3,-0.6,0.6,0,8.5,   !创建键槽矩形

VSBV,1,4         !减去键槽矩形

NUMCMP,VOLU    !压缩体编号

WPAVE,12,0,2.5   

VSBV,2,1,,,KEEP     !右侧圆柱与底板布尔运算

NUMCMP,VOLU    !压缩体编号

CYL4,0,0,2, , , ,1.5

CYL4,0,0,1.5, , , ,-2.5  !创建小圆柱体内孔

VSBV,1,4

VSBV,6,5          !布尔运算减去内部两个圆柱

VADD,ALL         !布尔加操作

!**************定义单元与材料****************

ET,1,SOLID187   !定义单元类型为10节点4面体实体单元

MPTEMP,,,,,,,, 

MPTEMP,1,0 

MPDATA,EX,1,,2.06E11

MPDATA,PRXY,1,,0.3 

MPTEMP,,,,,,,, 

MPTEMP,1,0 

MPDATA,DENS,1,,7800  !定义材料属性

ESIZE,1,0,             !网格尺寸设置为1

VMESH,ALL            !自由分网

!**************定义约束与载荷****************

LPLOT

LSEL,S, , ,2,3

LSEL,A, , ,21,22

LSEL,A, , ,87

LSEL,A, , ,89

DL,ALL, ,UZ,    !限制以上所选线条Z向自由度

ALLSEL

LSEL,S, , ,46

LSEL,A, , ,49

LSEL,A, , ,74

LSEL,A, , ,76

LSEL,A, , ,78,80,1

LSEL,A, , ,66

DL,ALL, ,ALL,   !限制以上所选线条的所有自由度

ALLSEL

/PNUM,LINE,0    !取消线编号

/PNUM,AREA,1   !显示面编号

SFA,24,1,PRES,1e6

SFA,26,1,PRES,1e6

SFA,17,1,PRES,1e6   !在小轴孔的内表面和轴台上加压力1e6

SFA,32,1,PRES,1e7   !在轴孔轴台上加载压力1e7

SFA,28,1,PRES,1e5   !在键槽一侧加载压力1e5

/SOL

SOLVE

FINISH

!**************结果后处理****************

/POST1

PLNSOL, U,X, 2,1.0 

PLNSOL, U,Y, 2,1.0  

PLNSOL, U,Z, 2,1.0       !显示X、Y、Z方向的位移

PLNSOL, S,X, 2,1.0       !显示X方向的应力

PLNSOL, S,EQV, 2,1.0     !显示等效应力

---

---

应力动画：

结语：由于网格差异，本命令流与视频中的求解结果有细微差别，读者重在熟悉了解建模分析过程。