行波效应例子

行波效应的例子，三根梁的平面刚架，两个固定基础。
1）第一段命令流是不考虑行波效应，约束基础，在全结构上施加加速度时程，
2）是不考虑行波效应，按照懒兄说的大质量法，在基础上施加同样加速度时程，得到的结果与1）在全结构施加加速度是一样的。
3）考虑行波效应，大质量法，两个基础上作用不一样的加速度历程。
1）
!x方向基础加速度，两脚固定刚架，无行波效应的命令流
/UNITS,SI
/PREP7
ET,1,Beam3
MP,EX,1,210E9
MP,PRXY,1,0.3
MP,DENS,1,7800
R,1,3E-4,2.5E-9,0.01
N,1,0,0,0
N,2,10,0,0
N,3,20,0,0
N,4,0,-10,0
N,5,20,-10,0
E,1,2
E,2,3
E,4,1
E,5,3
D,4,all,
D,5,all,
dmprat,0.02
EPLOT
/solu
*dim,baseacel,array,500 ! 定义正弦波的“基础加速度”, 500时间点
*do,i,1,500
baseacel(i)=0.1*sin(i*0.2) !
*enddo
NSUBST,1, , ,1 !1个子步
OUTRES,ALL,1 !输出每个子步的结果
ANTYPE,TRANS !时程分析
*do,i,1,500
acel,baseacel(i),0,0
TIME,i*0.1
solve
*enddo
/POST26
NSOL,2,2,U,x,Ux-at-2
PLVAR,2 !plot displacement time history
deriv,3,2,1,,v2 ! v=dy/dt
deriv,4,3,1,,a2 ! a=dv/dt
!QUOT,9,2,10, , , , ,1,1,
!plvar,9
/wait,3
plvar,2,3,4 ! ! plot disp., velocity and acceleration history together
fini
/eof

2）
!x方向基础加速度，两脚固定刚架，
/UNITS,SI
/PREP7
ET,1,Beam3
MP,EX,1,210E9
MP,PRXY,1,0.3
MP,DENS,1,7800
R,1,3E-4,2.5E-9,0.01
N,1,0,0,0
N,2,10,0,0
N,3,20,0,0
N,4,0,-10,0
N,5,20,-10,0
E,1,2
E,2,3
E,4,1
E,5,3
D,4,all,
D,5,all,
EPLOT
!!!!Add large mass!!!
ET,2,MASS21
KEYOPT,2,3,4 ! 2D without rotational inertial
R,2,1e5,1e5,1e5,1e5,1e5,1e5,
type,2
real,2
mat,1
e,4
e,5
DDELE,4,UX ! 去掉基础上待施加加速度方向的约束
ddele,5,ux
dmprat,0.02 ! 全结构阻尼比0.02
FINISH
/solu
*dim,baseacel,array,500 ! 定义正弦波的“基础加速度”, 500时间点
*do,i,1,500
baseacel(i)=0.1*sin(i*0.2) !
*enddo
NSUBST,1, , ,1 !1个子步
OUTRES,ALL,1 !输出每个子步的结果
ANTYPE,TRANS !时程分析
*do,i,1,500
f,4,fx,1e5*baseacel(i) ! F=m*a
f,5,fx,1e5*baseacel(i) ! 两基础上同步施加一样的加速度，等于没有行波效应
TIME,i*0.1
solve
*enddo
/POST26
NSOL,2,2,U,x,Ux-at-2 ! 2节点的绝对位移，不正确
PLVAR,2 !plot displacement time history
NSOL,5,5,U,x,Ux-at-2 ! 基础的绝对位移
ADD,8,2,5, , , , ,1,-1,1, ! 2节点位移与基础位移相减得到相对位移
plvar,8
deriv,3,8,1,,v2 ! v=dy/dt
deriv,4,3,1,,a2 ! a=dv/dt
/wait,3
plvar,3,4,8 ! ! plot disp., velocity and acceleration history together
fini
/eof

3）
!x方向基础加速度，两脚固定刚架，有行波效应的命令流
前面语句与上一个例子一样，
/solu
*dim,baseace1,array,500 ! 定义正弦波的“基础加速度”, 500时间点
*dim,baseace2,array,500
*do,i,1,500
baseace1(i)=0.1*sin(i*0.2) !
baseace2(i)=0.1*sin(i*0.2-0.4) !
*enddo
NSUBST,1, , ,1 !1个子步
OUTRES,ALL,1 !输出每个子步的结果
ANTYPE,TRANS !时程分析
*do,i,1,500
f,4,fx,1e5*baseace1(i) ! F=m*a
f,5,fx,1e5*baseace2(i) ! 第二个基础加速度比第一个相位滞后0.4,模拟一种行波效应
TIME,i*0.1
solve
*enddo
/POST26
NSOL,2,2,U,x,Ux-at-2 ! 2节点的绝对位移，不正确
PLVAR,2 !plot displacement time history
NSOL,5,5,U,x,Ux-at-2 ! 基础的绝对位移
ADD,8,2,5, , , , ,1,-1,1, ! 2节点位移与基础位移相减得到相对位移
plvar,8
deriv,3,8,1,,v2 ! v=dy/dt
deriv,4,3,1,,a2 ! a=dv/dt
/wait,3
plvar,3,4,8 ! ! plot disp., velocity and acceleration history together
fini
/eof