ansys之——浇筑混凝土 

!大伙看看,有何问题,如何改进?
!100*80*10基岩上浇筑混凝土50*40*10,每三天浇筑1米高(第一天浇完,剩下两天窝工),
!共用一个月时间,分为十层(layer)浇筑,模型、条件均为假设
!建模
/filename,test
/PREP7
BLOCK,,50,,10,,40,
BLOCK,-25,75,-10,0,-20,60
ET,1,70
LSEL,S,,,9,12,1
LESIZE,ALL,,,10
LSEL,S,,,21,24,1
LESIZE,ALL,,,20
LSEL,S,,,2,4,2
LSEL,A,,,5,7,2
LESIZE,ALL,,,10
LSEL,S,,,14,16,2
LSEL,A,,,17,19,2
LESIZE,ALL,,,20
LSEL,S,,,1,3,2
LSEL,A,,,6,8,2
LESIZE,ALL,,,10
LSEL,S,,,13,15,2
LSEL,A,,,18,20,2
LESIZE,ALL,,,5
allsel
MP,DENS,1,2400.0 !混凝土材料
MP,KXX ,1,300.89
MP,C,1,0.94500
MAT,1
VMESH,1
MP,DENS,2,2600.0 !基岩材料
MP,KXX ,2,300.89
MP,C,2,0.94500
MAT,2
VMESH,2
nummrg,all
!热分析
/SOLU
NROPT,FULL !Specifies the Newton-Raphson options in full transient analysis
ESEL,S,MAT,,2 !MAT2 IS 基岩
NSLE,S
IC,all,TEMP,16.4, !加基岩初温
ASEL,S,,,7,9,1
ASEL,A,,,11,12,1
NSLA,S,1
SF,all,HFLUX,0 !加基岩绝热边界条件
NSEL,S,LOC,Y,-0.1,0.1
ASEL,S,,,3
NSLA,U,1
SF,ALL,CONV,2016,20 !加基岩第三边界条件(和空气接触面)
!加初始条件
ALLSEL,ALL
ESEL,U,MAT,,2
NSLE,S
EKILL,ALL !KILL 混凝土
IC,all,TEMP,35, !混凝土浇筑时温度为35度
ANTYPE,TRANSIENT,new !分析类型
!日子的流逝
*DO,LAYER,1,10,1
!激活第N层单元
ALLSEL,ALL
NSEL,S,LOC,Y,(LAYER-1),LAYER !第一层从Y=0~1米,第二层从Y=1~2米,...
ESLN,S ,1
EALIVE,ALL
*DO,DAY,LAYER*3-2,LAYER*3,1 !每三天浇筑一层
ALLSEL,ALL
ASEL,S,,,1,2,1
ASEL,A,,,5,6,1
NSLA,S,1
NSEL,R,LOC,Y,0,LAYER
NSEL,A,LOC,Y,LAYER-0.1,LAYER+0.1
SF,ALL,CONV,2016,20 !加混凝土第三类对流边界条件
*DO,LOOP,1,LAYER,1
ALLSEL,ALL
NSEL,R,LOC,Y,LOOP-1,LOOP
ESLN,S,1
TDAY=DAY-(LOOP-1)*3 !已经完工的天数
HE00=47880*(TDAY/(0.862+TDAY)-(TDAY-1)/(0.862+TDAY-1))
BFE,ALL,HGEN, ,HE00 !加水化热
*ENDDO
!计算设置
ALLSE
TRNOPT,FULL
LUMPM,0
TIME,DAY
AUTOTS,0
DELTIM,1, , ,1
KBC,0
TSRES,ERASE
OUTRES,ALL,ALL,
SOLVE
*ENDDO
ESEL,S,MAT,,1
NSLE,S,
SFEDELE,ALL,ALL,CONV !删对流边界条件
SFDELE,ALL,CONV
*ENDDO
FINISH

!结构分析
/PREP7
ET,1,SOLID65 !变热单元为结构单元
*DIM,EXX,ARRAY,30 !考虑变化的EX
EXX(1)=0.325E10,0.57778E10,0.78E10,0.94545E10,0.10833E11,0.12E11,0.13E11,0.13867E11,0.14625E11,0.15294E11, 0.15889E11, 0.1642E11 ,0.169E11, 0.17333E11, 0.17727E11, 0.18087E11,0.18417E11,0.1872E11
EXX(19)=0.190E11, 0.19259E11, 0.195E11, 0.19724E11, 0.19933E11, 0.20129E11,0.20312E11, 0.20485E11, 0.20647E11, 0.208E11, 0.20944E11, 0.21081E11
*DO,I,1,30,1 !定义材料,混凝土浇筑完每过一天变一种材料
MP,DENS,I,2400
MP,EX,I,EXX(I)
MP,PRXY,I,0.167
MP,ALPX,I,0.9E-5
MP,REFT,I,15
*ENDDO
MP,DENS,31,2600 !定义基岩材料
MP,EX,31,0.20800E+11
MP,PRXY,31,0.167
MP,ALPX,31,0.9E-5
ESEL,S,MAT,,,2
MPCHG,31,ALL, !!变热材料为结构材料
ALLSEL
/SOLU
NROPT,FULL !Specifies the Newton-Raphson options in a full transient analysis
NLGEOM,ON
NSLA,S,,,7,9,1
NSLA,A,,,11,12,1
D,all,ALL !加基岩约束
!KILL THE CONCRETE ELEMENT
ESEL,U,MAT,,1
NSLE,S
EKILL,ALL !KILL 混凝土
*DO,DAY,1,30,1 !随时间改变,变换材料
*DO,LAYER,1,10
*IF,DAY,GT,LAYER*3-3,THEN
NSEL,S,LOC,Y,LAYER-1,LAYER
ESLN,S,1
EALIVE,ALL !ACTIVE NEXT LAYER
MPCHG,DAY-(LAYER-1)*3,ALL, !CHANG MAT
ALLSEL,ALL
*ENDIF
*ENDDO
ALLSEL,ALL
ACEL,0,0,-9.8, !GRAVITY LOAD
LDREAD,TEMP,,,DAY, ,'TEST','rth',' ' !TEMP LOAD Reads results from the results file and applies them as loads.
CNVTOL,F, ,0.2,2,200, !Sets convergence values for nonlinear analyses.
TIME,DAY
AUTOTS,0
DELTIM,1, , ,1
KBC,0
TSRES,ERASE !Defines an array of keytimes at which the time-stepping strategy changes
OUTRES,ALL,ALL,
SOLVE
*ENDDO
!1、定义重力集散地是应为正值:ACEL,0,0,9.8
!2、砼单元边长(1*4*5)相差5倍,对计算精度的影响会不会较大?
!3、热单元SOLID70对应的结构单元为SOLID45,改为SOLID65是否合适?
!4、原分析得到的结果与实际情况比较如何?
!5、如何体现气温的变化?

ANSYSCAE结构CAE

ansys之——浇筑混凝土 的评论1条

  • linyimodaochi
    0
    在运行这个命令流的时候出候出现下面的警告,请问怎么解决?<br/>“Cumulative iteration 2 may have been solved using different model or <br/>boundary condition data than currently stored. POST1 results may be <br/>erroneous unless you RESUME from a Jobname.DB file for this substep.”

ansys之——浇筑混凝土&nbsp;的相关案例教程

!ANSYS命令流学习笔记6 !热应力分析 !学习重点: !1、 理解热力耦合的直接法和间接法 !间接法:先进行热分析,然后将求得的节点温度作为载荷施加到结构应力分析中。 !直接法:直接采用具有温度和位移自由度的耦合单元,同时得到热分析和结构应力分析的结果。直接法又分弱耦合和强耦合选择强耦合时,形成不对称矩阵,线性系统可以直接求解。选择弱耦合时,对称矩阵,还是把热和结构分别进行求解,并将热结果施加
点击蓝字 关注我们 好久没有更新算例了,这期更新一个小算例,用强度折减法计算边坡的稳定性,用ANSYS软件计算,ABAQUS的算例我前面写了两篇,感兴趣的可以看看。 边坡的尺寸及参数与之前的ABAQUS的边坡算例相同。模型如下。 接下来讲解一下建模的过程。先定义一下单元的类型。这里采用平面应变单元,PLANE42单元。 !定义单元类型ET,1,PLANE82     !定义边坡围岩单元KEYOPT
本文以二维静态磁场为例,介绍一下使用远场单元注意事项,并给出一个简单的APDL算例,软件版本ANSYS19.0。 一、问题介绍及注意事项 对于ANSYS二维静态磁场分析,磁力线总是平行或垂直于边界的,有时与实际情况是不符的,这时候就要引入infin110等远场单元。下面就以infin110为例,列出几项远场单元的注意事项: 1)infin110只需在最外层划分一层单元。 2)最外层的infin11
极限载荷法是求解结构能承受的极限载荷的一种方法。极限载荷法是一种强度分析方法,注意要与结构稳定性分析区分开。下面给出一个带有缺陷的管道结构极限载荷APDL算例,最后给出几点注意事项,供读者参考。 ! ***************环境设置************************finish/clear/filn,file/title,!基本参数h1=108!外径h2=108-2*8!内径h
最近在考虑自己编写的程序和商用软件的验证问题,有限元结构分析中最关键的一环就是刚度矩阵的获得,如果涉及到模态分析,还有质量矩阵。考虑到商业软件的成熟性,可以用ANSYS生成的刚度矩阵做参照来看自己编写的程序是否正确,因此如何提取ANSYS中结构的刚度矩阵,并进行随后的验证或者二次开发是一个问题。 https://www.jishulink.com/content/post/1796144 受上述帖
影响力
粉丝
内容
获赞
收藏
    项目客服
    培训客服
    1 1