求ANSYS做可靠性方面的资料

finish
/clear
/com,ylrq
!环境设置
/filn,Reliability
/title,Reliability Design
!定义参数
*set,ex1,200000 !材料的弹性模量
*set,prxy1,0.3 !材料的泊松比
*set,D,1000 !容器的内径均值
*set,t,70 !容器的壁厚均值
*set,load,28 !容器的内压均值
*set,yies,175 !材料的屈服极限均值
!*set,Z,0 !极限状态方程，初值设为0
!前处理
/prep7
!et,1,42,,,1 !定义42号轴对称单元
et,1,plane82 !定义plane82单元
keyopt,1,3,1 !设定轴对称选项
mp,ex,1,ex1 !定义材料的弹性模量
mp,nuxy,1,prxy1 !定义材料的泊松比
!建立模型
k,1, !定义坐标原点
circle,1,D/2 !生成容器的内径均值
circle,1,D/2+t !生成容器的外径均值
l,2,6
L,3,7
l,5,9
al,1,5,9,10
al,4,8,9,11
ldel,2,3,1
ldel,6,7,1
kdel,1
kdel,4
kdel,8
aplot !显示面积
!划分网格
lesize,9,,,7 !定义将9号线划分成7
lesize,10,,,7 !定义将10号线划分成7个等分单元
lesize,11,,,7 !定义将11号线划分成7个等分单元
lesize,1,,,90 !定义将1号线划分成90个等分单元
lesize,4,,,90 !定义将4号线划分成90个等分单元
lesize,5,,,90 !定义将5号线划分成90个等分单元
lesize,8,,,90 !定义将8号线划分成90个等分单元
amesh,all,all !划分网格
!加载与求解
/solu
nsel,s,loc,x,-0.01,0.01 !选择x坐标在-0.01～0.01之间所有节点
d,all,ux !约束所有节点的X向位移
allsel,all
d,1,uy !约束1号节点的Y向位移
sfl,1,pres,load !在1号线上施加压力载荷
sfl,4,pres,load !在4号线上施加压力载荷
solve !求解
finish
!后处理
/post1
nsort,s,eqv !等效应力按降序排列
*get,maxstr,sort,,max !取出最大等效应力
Z=yies-maxstr !定义极限状态方程Z(x)=σs-σemax
lgwrite,ylrq11,txt !定义概率分析文件
finish
/PDS !进入概率分析模块
PDANL,'ylrq11','txt',' ' !选定分析文件
PDVAR,load,GAUS,28,4,0,0 !载荷为高斯分布，均值为28MPa，标准差为4MPa
PDVAR,D,GAUS,1000,5,0,0 !容器的内径为高斯分布，均值为1000mm，标准差为5mm
PDVAR,t,GAUS,70,0.35,0,0 !容器的壁厚为高斯分布，均值为70mm，标准差为0.35mm
PDVAR,YIES,GAUS,175,15,0,0 !材料屈服极限为高斯分布，均值为175MPa，标准差为15MPa
PDVAR,Z,RESP !定义Z为输出随机变量
PDMETH,MCS,LHS !选择分析方法为M.C.方法
PDLHS,500,1,RAND, ,'ALL ', , , ,CONT !定义抽样50,000次
PDEXE,ylrq11,SER,0,DEL,ylrq11 !执行概率分析
PDPROB,ylrq11,Z,LT,0,' ',0.95, !查看Z小于0、置信度为95%时的概率
pdsens,ylrq11,Z !Z灵敏度显示
pdshis,ylrq11,D !绘制D取样分布柱状图
pdcdf,ylrq11,z,emp,0.95,100 !绘图显示Z的分布函数
pdwrite,report !生成可靠性分析报告