求助！ANSYS热分析问题

你好，我是利用表载荷加载热流密度模拟移动的激光热源，不知是加载问题还是分析设置有问题，下面是全部命令流，请帮忙看看，谢谢！
/clear,nostart
/filname,ceramicthinwall_thermal_analysis
/title,ceramicthinwall_thermal_analysis
/units,si !定义国际制单位
/prep7
ET,1,SOLID70 !定义单元类型
ET,2,SURF152
KEYOPT,2,4,1 !存在中间节点
KEYOPT,2,5,0 !没有孤立节点
KEYOPT,2,8,1 !施加热流密度，忽略对流
!**********************************************************************
!定义单元类型及材料属性
!**********************************************************************
MPTEMP,,,,,,,,
MPTEMP,1,20
MPTEMP,2,200
MPTEMP,3,400
MPTEMP,4,600
MPTEMP,5,1530
MPTEMP,6,1650
MPTEMP,7,2000
MPDATA,KXX,1,,17
MPDATA,KXX,1,,15
MPDATA,KXX,1,,15
MPDATA,KXX,1,,16
MPDATA,KXX,1,,20
MPDATA,KXX,1,,20.5
MPDATA,KXX,1,,21
MPTEMP,,,,,,,,
MPTEMP,1,20
MPTEMP,2,200
MPTEMP,3,400
MPTEMP,4,600
MPTEMP,5,1530
MPTEMP,6,1650
MPTEMP,7,2000
MPDATA,C,1,,500
MPDATA,C,1,,580
MPDATA,C,1,,595
MPDATA,C,1,,615
MPDATA,C,1,,760
MPDATA,C,1,,840
MPDATA,C,1,,730
MPTEMP,,,,,,,,
MPTEMP,1,20
MPTEMP,2,200
MPTEMP,3,400
MPTEMP,4,600
MPTEMP,5,1530
MPTEMP,6,1650
MPTEMP,7,2000
MPDATA,DENS,1,,4420
MPDATA,DENS,1,,4420
MPDATA,DENS,1,,4420
MPDATA,DENS,1,,4420
MPDATA,DENS,1,,4420
MPDATA,DENS,1,,4420
MPDATA,DENS,1,,4420
MPTEMP,,,,,,,,
MPTEMP,1,20
MPTEMP,2,600
MPTEMP,3,1400
MPTEMP,4,1800
MPDATA,KXX,2,,39
MPDATA,KXX,2,,9.2
MPDATA,KXX,2,,5.9
MPDATA,KXX,2,,7.1
MPTEMP,,,,,,,,
MPTEMP,1,27
MPTEMP,2,127
MPTEMP,3,227
MPTEMP,4,327
MPTEMP,5,427
MPTEMP,6,527
MPTEMP,7,627
MPTEMP,8,727
MPTEMP,9,827
MPTEMP,10,927
MPTEMP,11,1027
MPTEMP,12,1127
MPTEMP,13,1227
MPTEMP,14,1327
MPTEMP,15,1527
MPTEMP,16,1727
MPDATA,C,2,,785
MPDATA,C,2,,942
MPDATA,C,2,,1046
MPDATA,C,2,,1109
MPDATA,C,2,,1151
MPDATA,C,2,,1203
MPDATA,C,2,,1224
MPDATA,C,2,,1235
MPDATA,C,2,,1256
MPDATA,C,2,,1272
MPDATA,C,2,,1285
MPDATA,C,2,,1297
MPDATA,C,2,,1308
MPDATA,C,2,,1308
MPDATA,C,2,,1308
MPDATA,C,2,,1308
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,2,,3900
!*CSET,1,2, 2,3,
MPCOPY, ,2,3
TBCOPY,ALL,2,3
!**********建立模型***************
L1=0.1 !定义参数
W1=0.1
H1=0.009
L2=0.02
W2=0.01
H2=0.009
L3=0.015
W3=0.004
H3=0.0003
R=0.002
!***************定义点************
K,1,0,0,0,
K,2,L1,0,0,
K,3,L1,W1,0,
K,4,0,W1,0,
K,5,0,0,H1,
K,6,L1,0,H1,
K,7,L1,W1,H1,
K,8,0,W1,H1,
K,9,(L1-L2)/2,(W1-W2)/2,0,
K,10,(L1+L2)/2,(W1-W2)/2,0,
K,11,(L1+L2)/2,(W1+W2)/2,0,
K,12,(L1-L2)/2,(W1+W2)/2,0,
K,13,(L1-L2)/2,(W1-W2)/2,H2,
K,14,(L1+L2)/2,(W1-W2)/2,H2,
K,15,(L1+L2)/2,(W1+W2)/2,H2,
K,16,(L1-L2)/2,(W1+W2)/2,H2,
K,17,(L1-L3)/2,(W1-W3)/2,H2,
K,18,(L1+L3)/2,(W1-W3)/2,H2,
K,19,(L1+L3)/2,(W1+W3)/2,H2,
K,20,(L1-L3)/2,(W1+W3)/2,H2,
K,21,(L1-L3)/2,(W1-W3)/2,H2+H3,
K,22,(L1+L3)/2,(W1-W3)/2,H2+H3,
K,23,(L1+L3)/2,(W1+W3)/2,H2+H3,
K,24,(L1-L3)/2,(W1+W3)/2,H2+H3,
K,25,(L1-L3)/2,L1/2,H2+H3+R,
K,26,(L1+L3)/2,L1/2,H2+H3+R,
!***************连线************
LSTR,1,2
LSTR,2,3
LSTR,3,4
LSTR,4,1
LSTR,1,5
LSTR,2,6
LSTR,3,7
LSTR,4,8
LSTR,5,6
LSTR,6,7
LSTR,7,8
LSTR,8,5
LSTR,9,10
LSTR,10,11
LSTR,11,12
LSTR,12,9
LSTR,9,13
LSTR,10,14
LSTR,11,15
LSTR,12,16
LSTR,13,14
LSTR,14,15
LSTR,15,16
LSTR,16,13
LSTR,17,18
LSTR,18,19
LSTR,19,20
LSTR,20,17
LSTR,17,21
LSTR,18,22
LSTR,19,23
LSTR,20,24
LSTR,21,22
LSTR,22,23
LSTR,23,24
LSTR,24,21
LSTR,25,26
LARC,21,25,24,0.002
LARC,24,25,21,0.002
LARC,22,26,23,0.002
LARC,23,26,22,0.002
!***************建面************
AL,1,2,3,4
AL,1,5,9,6
AL,2,6,10,7
AL,3,7,11,8
AL,4,5,12,8
AL,9,10,11,12
AL,13,14,15,16
AL,13,17,21,18
AL,14,18,22,19
AL,15,19,23,20
AL,16,17,24,20
AL,21,22,23,24
AL,25,26,27,28
AL,25,29,33,30
AL,26,31,34,30
AL,27,32,35,31
AL,28,29,36,32
AL,33,34,35,36
AL,36,38,39
AL,34,40,41
AL,35,39,37,41
AL,33,38,40,37
!***************建体************
VA,1,2,3,4,5,6
VA,7,8,9,10,11,12
VA,13,14,15,16,17,18
VA,19,20,21,22,18
!**********实体布尔运算***********
VOVLAP,1,2,3,4 !搭接运算
VGLUE,6,3,4,5 !粘结运算(搭接后体的编号改变)
!**********定义模型材料和单元属性***********
Vsel,s,,,6
Vsel,a,,,5
Vatt,1,,1
ALLSEL,ALL
VSEL,s,,,3
Vatt,2,,1
ALLSEL,ALL
VSEL,s,,,4
Vatt,3,,1
ALLSEL,ALL
!**********扫掠网格划分薄壁结构3,4***********
LESIZE,32,,,3,,,,,1
LESIZE,28,,,20,,,,,1
LESIZE,27,,,75,,,,,1
LESIZE,25,,,75,,,,,1
LESIZE,38,,,20,,,,,1
LESIZE,39,,,20,,,,,1
VSEL,s,,,3,4
VSWEEP,ALL
ALLSEL,ALL
!**********自由网格划分基座5,6***********
ESIZE,0.001,0, !交互操作自动生成的命令流
MSHAPE,1,3D
MSHKEY,0
CM,_Y,VOLU
VSEL, , , , 5
CM,_Y1,VOLU
CHKMSH,'VOLU'
CMSEL,S,_Y
!*
VMESH,_Y1
!*
CMDELE,_Y
CMDELE,_Y1
CMDELE,_Y2
!******************************************************
ESIZE,0.005,0,
CM,_Y,VOLU
VSEL, , , , 6
CM,_Y1,VOLU
CHKMSH,'VOLU'
CMSEL,S,_Y
!*
VMESH,_Y1
!*
CMDELE,_Y
CMDELE,_Y1
CMDELE,_Y2
!************************************************
!SMRT,off
!ESIZE,0.0005,,
!Vmesh,5
!SMRT,off
!ESIZE,0.005,,
!Vmesh,6
!ALLSEL,ALL
!**********建立表面效应单元***********
TYPE,2
MAT,3
REAL,
ASEL,S,AREA,,21
ASEL,A,AREA,,22
NSLA,S,1
ESURF
ALLSEL
!**********定义热流密度表载荷***********
!**********参数定义***********
tm=3
tinc=0.04
esize=0.2e-3
v=0.005
R=2e-3
pi=3.1415926
max_time=76
max_x=76
max_y=21
power=800
power_max=800/(pi*R*R)
!**********表载荷定义***********
*DIM,laser,TABLE,MAX_X,MAX_Y,MAX_TIME,X,Y,TIME
*DO,K,1,MAX_TIME,1
*DO,I,1,MAX_X,1
laser(I,0,K)=(I-1)*ESIZE
*ENDDO
*DO,J,1,MAX_Y,1
laser(0,J,K)=(J-1)*ESIZE
*ENDDO
*DO,I,1,MAX_X,1
*DO,J,1,MAX_Y,1
YCENTER=L1/2
XCENTER=V*(K-1)*TINC+(L1-L3)/2
DISTANCE=SQRT(((I-1)*ESIZE-XCENTER)**2+((J-1)*ESIZE-YCENTER)**2)
*IF,DISTANCE,LE,R,THEN
laser(I,J,K)=power_max !激光的表面热流
*ELSE
laser(I,J,K)=0
*ENDIF
*ENDDO
*ENDDO
laser(0,0,K)=(K-1)*TINC
*ENDDO
!**********进行稳态分析***********
/SOLU
NROPT,FULL,, !设置牛顿-拉夫森选项
ESEL,S,MAT,,2
ESEL,A,MAT,,3
Ekill,ALL !杀死熔覆层及表面效应单元
ALLSEL,ALL
TOFFST,273 !设置温度偏移量
ESEL,S,MAT,,1
NSEL,S
D,ALL,,25,,,,TEMP,,,,, !定义基座初始温度
ALLSEL,ALL
ANTYPE,TRANS !定义为瞬态热分析
TIMINT,OFF !关闭时间积分，设定为稳态分析
TIME,1E-6 !设定只有一个子步的时间很小的载荷步
KBC,0 !斜坡方式施加载荷
DELTIM,1 !设定求解时间子步
SOLVE !求解
!**********进行瞬态分析***********
/SOLU
ALLSEL,ALL
DDELET,ALL,TEMP !删除稳态分析中定义的节点温度
ASEL,S,,,2,3,4,5,24,25 !施加对流换热系数（应该为随温度变化）
ASEL,A,,,7,23
SFA,ALL,,CONV,50,25
ALLSEL,ALL
ASEL,S,,,14,15,16,17,19,20,21,22
SFA,ALL,,CONV,750,25

!**********循环加载求解***********
ALLSEL,ALL
*SET,M,1
*DO,T,0.01,tm,tinc
!**********逐步激活激光照射到的薄壁件单元***********
VSEL,S,MAT,,2
VSEL,A,MAT,,3
NSLV,S,1
NSEL,R,LOC,X,(M-1)*0.015/75+(L1-L3)/2,(M-1)*0.015/75+2*R+(L1-L3)/2
ESLN,S,1
EALIVE,ALL
ALLSEL
ESEL,S,type,,2
NSLE,S,ALL,,
NSEL,R,LOC,X,(M-1)*0.015/75+(L1-L3)/2,(M-1)*0.015/75+2*R+(L1-L3)/2
ESLN,S,1
EALIVE,ALL
ALLSEL
!**********施加薄壁件第一层热源***********
TIME,t
TIMINT,ON
KBC,1
AUTOTS,ON
DELTIM,,,,1
ESEL,s,TYPE,,2
SFE,ALL,1,HFLUX,,%laser%
ALLSEL
OUTRES,ALL,ALL
SOLVE
SFDELE,ALL,HFLUX !计算后删除热源，便于下一步加载
*SET,M,M+1
*enddo
FINISH

分析设置部分截个图看看