ansys classical 疲劳分析apdl

韩峰

2016年1月19日 15:20

浏览：5476 收藏：2

! ***************环境设置***************
/units,si
/title, Fatigue analysis of cylinder with flat head
! ***************参数设定***************
Di=1000 ! 筒体内径
t=20 ! 筒体厚度
hc=nint(4*sqrt(Di/2*t)/10)*10 ! 模型中筒体长度
tp=60 ! 平板封头厚度
r1=10 ! 平板封头外测过渡圆弧半径
r2=10 ! 平板封头内侧应力释放槽圆弧半径
exx=2e5 ! 材料弹性模量
mu=0.3 ! 材料泊松比
p1=2 ! 最高工作压力
p3=2.88 ! 水压试验压力
n1=2e4 ! 最高/最低压力循环次数
n2=5 ! 水压试验次数
! ***************前处理***************
/prep7
et,1,82 ! 设定单元类型
keyopt,1,3,1 ! 设定周对称选项
mp,ex,1,exx ! 定义材料弹性模量
mp,nuxy,1,mu ! 定义材料泊松比
! ******* 建立模型 *******
k,1,0,0 ! 定义关键点
k,2,Di/2+t,,
k,3,Di/2+t,-(tp+hc)
k,4,Di/2,-(tp+hc)
k,5,Di/2,-tp
k,6,Di/2-r2,-tp ! 定义应力释放槽圆弧中心关键点
k,7,0,-tp
l,1,2 ! 生成线
l,2,3
l,3,4
l,4,5
l,5,7
l,7,1
LFILLT,1,2,r1 ! 生成外测过渡圆弧
al,all ! 生成子午面
CYL4, kx(6),ky(6), r2,180 ! 生成应力释放槽面域
ASBA,1,2 ! 面相减
wprot,,,90 ! 旋转工作平面
wpoff,,,kx(6)-3*r2 ! 移动工作平面
asbw,all ! 用工作平面切割子午面
wprot,,90 ! 旋转工作平面
wpoff,,,tp+r2 ! 移动工作平面
asbw,all ! 用工作平面切割子午面

esize,5 ! 设定单元尺寸
MSHKEY,1 ! 设定映射剖分
amesh,1 ! 映射剖分面1
amesh,3 ! 映射剖分面3
esize,2 ! 设定单元尺寸
MSHKEY,0 ! 设定自由剖分
amesh,4 ! 自由剖分面4
fini ! 退出前处理
! ***************求解***************
/solu ! 筒体端部施加轴向约束
dl,3,,uy ! 筒体端部施加轴向约束
dl,6,,symm ! 平板封头对称面施加对称约束

time,1 ! 载荷步1
lsel,s,,,8 ! 选择内表面各线段
lsel,a,,,11,13
lsel,a,,,15
cm,lcom1,line ! 生成内表面线组件
SFL,all,PRES,p1, ! 内表面施加内压
alls ! 全选
solve ! 求解
fini ! 退出求解器
! ***************后处理***************
/post1 ! 进入后处理
FTSIZE,1,2,2, ! 设定疲劳评定的位置数、事件数及载荷数

FP,1,1e1,2e1,5e1,1e2,2e2,5e2 ! 根据疲劳曲线输入S－N数据
FP,7,1e3,2e3,5e3,1e4,2e4,5e4
FP,13,1e5,2e5,5e5,1e6, ,
FP,19, ,
FP,21,4000,2828,1897,1414,1069,724
FP,27,572,441,331,262,214,159
FP,33,138,114,93.1,86.2, ,
FP,39, ,

! ****** 水压试验循环 ******
fs,4760,1,1,1,0,0,0,0,0,0 ! 储存节点4760对应其第一载荷的应力
set,1,last ! 读入第一载荷步数据
FSNODE,4760,1,2 ! 储存节点4760对应其第二载荷的应力
fe,1,n2,p3/p1 ! 设定事件循环次数及载荷比例系数
! ****** 最高/最低压力循环 ******
fs,4760,2,1,1,0,0,0,0,0,0 ! 储存节点4760对应其第一载荷的应力
set,1,last ! 读入第一载荷步数据
FSNODE,4760,2,2 ! 储存节点4760对应其第二载荷的应力
FE,2,n1,1, ! 设定事件循环次数及载荷比例系数
FTCALC,1 ! 进行疲劳计算（并记录使用系数）
fini

!~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
计算结果如下：

PERFORM FATIGUE CALCULATION AT LOCATION 1 NODE 0

*** POST1 FATIGUE CALCULATION ***

LOCATION 1 NODE 4760
事件1： ****** 水压试验循环 ******
EVENT/LOADS 1 1 AND 1 2
PRODUCE ALTERNATING SI (SALT) = 285.16（应力幅值）
CYCLES USED/ALLOWED = 5.000/7779（实际循环数/许用循环数） = PARTIAL USAGE（局部损伤)=0.00064

事件2： ****** 最高/最低压力循环 ******
EVENT/LOADS 2 1 AND 2 2
PRODUCE ALTERNATING SI (SALT) = 198.03 WITH TEMP = 0.0000
CYCLES USED/ALLOWED = 0.2000E+05/ 0.2541E+05 = PARTIAL USAGE = 0.78719
CUMULATIVE FATIGUE USAGE = 0.78784