包络谱识别冲击振动在Ansys软件中如何仿真（一）

笔者工作之一：需要长期监控轴承的运行健康状况。

实际工作表明：包络谱法是识别轴承故障的有效方法。

包络谱法：当结构因为受到连续冲击而振动时，用包络谱法分析它的振动响应，就可以得出冲击的频率。在轴承监测中，轴承一旦损坏，会对轴承座产生周期性冲击，采集轴承座的振动响应，进行包络分析，可以立马得出冲击频率，如果这个冲击频率和轴承商家提供的轴承故障频率很接近，那么很有可能是轴承已经损坏。

笔者在Ansys软件平台下，使用APDL脚本语言：对一个结构进行连续冲击激励，然后提取结构上某点的振动响应，利用包络谱法分析该振动响应，果然提取出了冲击频率。本文具有一定水准。

 ---建模

FINISH$/CLEAR   !清空

/FILNAME,THE RESPONSE   !文件名字

/TITLE,SHELL181  !标题

!UNITS,S-M-KG-N  !单位制

/PREP7

!DEFINE ELEMENT TYPE AND MATERIAL

ET,1,SHELL181,,,2    !壳单元181

MP,EX,1,210E9        !弹性模量

MP,PRXY,1,0.3        !泊松比

MP,DENS,1,7850       !密度

!DEFINE SECTION

SECTYPE,1,SHELL   !截面形式

SECDATA,0.004     !截面尺寸

!DEFINE GEOMETRY

K,1,0,0$K,2,0.5,0    !关键点1和2

K,3,0,0.5$K,4,0.5,0.5  !关键点3和4

L,1,2$L,2,4$L,4,3$L,3,1  !由点画线

A,1,2,4,3    !由点画面

AATT,1,,1,,1   !指定单元，材料，截面

LESIZE,ALL,0.1 !指定单元尺寸

AMESH,ALL  ! 划分网格

!DEFINE BOUNDARY CONDITION

DL,1,,ALL,0   !约束线

ALLSEL    !全选

---模态分析

!MODAL ANALYSIS

/SOLU

ANTYPE,MODAL !模态分析

MODOPT,LANB,15 !提取15阶模态

MXPAND,15 !扩展15阶模态

SOLVE  !求解

!POST 

/POST1 !后处理

SET,LIST!列表模态频率

FINISH

---冲击振动时程分析（对节点17施加连续冲击）

NI=4*200$DT=1/200

*DIM,IMPACT,ARRAY,NI !定义参数

*VREAD,IMPACT(1),impact,txt !读取连续冲击时域数据

(F5.2)

/SOLU

ANTYPE,4 !瞬态分析

TRNOPT,FULL,,,,,HHT !完全法

TIMINT,ON !时间积分打开

*DO,I,1,NI !循环加载

TIME,I*DT

F,17,FZ,IMPACT(I) 

KBC,0$NSUBST,2,5,1

OUTRES,ALL,NONE

OUTRES,NSOL,ALL

NSEL,S,NODE,,7$CM,AT,NODE

OUTRES,A,LAST,AT

ALLSEL$SOLVE$SAVE

*ENDDO  !循环结束

---提取冲击振动响应（提取节点7的加速度响应）

/POST26

NSOL,2,7,ACC,Z !提取变量

*DIM,ACCE,ARRAY,NI!定义参数

VGET,ACCE(1),2 !将变量写入参数

*CFOPEN,ACCE,txt

*VWRITE,ACCE(1)!将参数写入文件

(F12.9)

*CFCLOS

以上APDL命令：对一个平板施加了连续冲击，并且提取了平板上另外一点的振动响应。

下一篇文章预告：

        1.对该平板振动响应进行包络分析，查看包络谱结果，是否抓住了连续冲击频率。

        2.附录以上分析的APDL源文件，以及连续冲击时域数据impact.txt等。

        3.笔者将工作中遇到的实际轴承故障与长期监测结果对比，论证包络谱分析的有效性。