拍现象与共振现象的区别

摘要：实际结构的共振现象中常常会出现拍现象，这让很多工程师误以为共振就会引起拍现象。本文从振动理论，结构仿真，信号实践三个角度阐述这两个现象是完全不一样的，并且给出实际结构的共振现象中常常会出现拍现象的原因。

---

拍：两个频率相近的波叠加之后会形成忽大忽小的幅值。

共振：在共振频率下，很小的激励便可产生很大的振动。

---

1 振动理论

查阅相关理论，很容易发现，共振就是结构振幅很大，从来不会提及振幅忽大忽小的现象。所以在理论中，并没有将共振现象和拍现象相提并论，相互混淆。即，理论上共振和拍是相区别的。

---

2 结构仿真

定义三自由振动系统，模态分析：

finish !初始化
/clear !清空所有数据
/filname,3dof! 定义文件名
/title, tansient car!定义文件标题
!
m1=5!质量1
m2=15!质量2
m3=20!质量3
k1=110000!刚度1
k23=50000!刚度2,3
c23=100!阻尼2,3
!
/prep7!进入前处理模块
et,1,mass21,,,4!定义质量单元
et,2,combin14,,,2!定义弹簧单元
r,1,m1!质量实常数 1
r,2,m2!质量实常数2
r,3,m3!质量实常数3
r,4,k1!刚度实常数4
r,5,k23,c23!刚度，阻尼实常数5
!
n,1,0,0!节点1
n,2,0,1!节点2
n,3,0,2!节点3
n,4,0,3!节点4
type,1!选择质量单元
real,1!实常数1
e,2!质量单元
real,2!实常数2
e,3!质量单元
real,3!实常数3
e,4!质量单元
type,2!选择弹簧单元
real,4!实常数4
e,1,2!弹簧单元
real,5!实常数5
e,2,3!弹簧单元
e,3,4!弹簧单元
!
d,all,ux! 约束X方向自由度，只留下Y自由度
d,1,all!约束轮胎位置
!
finish !初始化
/solu !进入求解模块
antype,2!模态分析
modopt,qrdamp,6  !QRDAMP法
!modopt,lanb,6 !LANB法
mxpand,6,,,yes! 提取结果
allsel!全选
solve! 求解
!
finish !初始化
/post1!进入后处理模块
set,list!提取模态频率

求解结果如下：

构建包含3个共振频率的激励信号，对该振动系统进行时程分析：

构建信号：

信号频域：

时程分析：

finish !初始化
/clear !清空所有数据
/filname,3dof! 定义文件名
/title, tansient car!定义文件标题
!
m1=5!质量1
m2=15!质量2
m3=20!质量3
k1=110000!刚度1
k23=50000!刚度2,3
c23=100!阻尼2,3
!
/prep7!进入前处理模块
et,1,mass21,,,4!定义质量单元
et,2,combin14,,,2!定义弹簧单元
r,1,m1!质量实常数 1
r,2,m2!质量实常数2
r,3,m3!质量实常数3
r,4,k1!刚度实常数4
r,5,k23,c23!刚度，阻尼实常数5
!
n,1,0,0!节点1
n,2,0,1!节点2
n,3,0,2!节点3
n,4,0,3!节点4
type,1!选择质量单元
real,1!实常数1
e,2!质量单元
real,2!实常数2
e,3!质量单元
real,3!实常数3
e,4!质量单元
type,2!选择弹簧单元
real,4!实常数4
e,1,2!弹簧单元
real,5!实常数5
e,2,3!弹簧单元
e,3,4!弹簧单元
!
d,all,ux! 约束X方向自由度，只留下Y自由度
!
finish! 初始化
ni=2560!扫频数据点个数
dt=1/256!扫频点时间间隔
*dim,impact,array,ni !定义参数
*vread,impact(1),gzh,txt !读取连续冲击时域数据
(f9.6) !定义格式
allsel!全选
/solu!进入求解模块
antype,4 !瞬态分析
trnopt,full,,,,,hht !完全法
timint,on !时间积分打开
nlgeom,off!忽略几何非线性
*do,i,1,ni !循环加载
time,i*dt! 时间点
d,1,uy,0.005*impact(i) !位移激励
kbc,0!斜坡荷载
nsubst,1,10,1!定义子步
allsel!全选
outres,all,last!输出每个荷载步的计算结果
solve!求解
save!保存
*enddo  !循环结束

提取响应加速度：

/POST26  !进入后处理模块

NSOL,2,4,ACC,Y !提取变量
*DIM,ACCY4,ARRAY,NI!定义参数
VGET,ACCY4(1),2 !将变量写入参数
*CFOPEN,ACCY4,txt
*VWRITE,ACCY4(1)!将参数写入文件
(F16.9)
*CFCLOS

NSOL,3,4,VEL,Y !提取变量
*DIM,VELY4,ARRAY,NI!定义参数
VGET,VELY4(1),3 !将变量写入参数
*CFOPEN,VELY4,txt
*VWRITE,VELY4(1)!将参数写入文件
(F16.9)
*CFCLOS

NSOL,4,4,U,Y !提取变量
*DIM,UY4,ARRAY,NI!定义参数
VGET,UY4(1),4 !将变量写入参数
*CFOPEN,UY4,txt
*VWRITE,UY4(1)!将参数写入文件
(F16.9)
*CFCLOS

NSOL,5,1,U,Y !提取变量
*DIM,UY1,ARRAY,NI!定义参数
VGET,UY1(1),5 !将变量写入参数
*CFOPEN,UY1,txt
*VWRITE,UY1(1)!将参数写入文件
(F16.9)
*CFCLOS

显示加速度响应的时域和频域：

从以上两个图可得：

1 当激励中包含结构共振频率时，结构会产生共振现象；

2 结构仿真中，共振时的时域响应不一定有拍现象；

---

3 信号实践

不难发现，只要信号频谱中存在相近的频率，就会从产生拍现象：

---

4 实际结构

本文的最后回到最初的问题：为什么实际结构的共振现象中常常会出现拍现象？

经过以上三个基本角度的分析，以及振动测试实践。可能存在两个原因，导致共振现象中出现拍现象：

第一：调制。如果在共振频率附近发生了调制，就会在共振频率附近出现多个相近频率，这样就满足了存在相近频率条件，所以产生拍现象。

第二：非线性。当结构发生共振现象时，测试得到的频谱在共振频率处最大，但在共振频率周边幅值也可能不小。这样就满足了存在相近频率条件，所以产生拍现象。即便周边的频率幅值为共振幅值的1/3，从时域上也可能观察到明显的拍现象。

---

5 总结

1 拍现象的根本原因是频谱存在相邻频率（幅值都较大）；

2 共振一般都会在频谱上产生相邻频率幅值都较大（调制和非线性），所以实际结构的共振现象中常常会出现拍现象；

3 时域上出现拍现象，不表示结构发生了共振。也有可能刚好存在频谱相近的两个激励。

4 在实际工作中，看到拍现象时，可以猜测发生了结构共振，但不足以下定论。