瞬态热分析实例

忘记了是那本书上的一个例子，放在这里共大家参考！

一钢铸件及其砂模的横截面尺寸如图所示:

砂模的热物理性能如下表所示:

	单位制
导热系数(KXX)	Btu/hr.in.oF	0.025
密度(DENS)	lbm/in3	0.254
比热(C)	Btu/lbm.oF	0.28

铸钢的热物理性能如下表所示:

	单位制	0oF	2643oF	2750oF	2875oF
导热系数	Btu/hr.in.oF	1.44	1.54	1.22	1.22
焓	Btu/in3	0	128.1	163.8	174.2

初始条件:铸钢的温度为2875oF，砂模的温度为80oF；

砂模外边界的对流边界条件：对流系数0.014Btu/hr.in2.oF，空气温度80oF；

求3个小时后铸钢及砂模的温度分布。

/Title, Casting Solidification

!进入前处理

/prep7

et,1,plane55
！定义单元

mp,dens,1,0.254
！定义砂模热性能

mp,kxx,1,0.025

mp,c,1,0.28

mptemp,1,0,2643,2750,2875
！定义铸钢的热性能

mpdata,kxx,2,1.44,1.54,1.22,1.22

mpdata,enth,2,0,128.1,163.8,174.2

mpplot,kxx,2

mpplot,enth,2

save

！创建几何模型

k,1,0,0,0

k,2,22,0,0

k,3,10,12,0

k,4,0,12,0

/pnum,kp,1

/pnum,line,1

/pnum,area,1

/Triad,ltop

kplot

a,1,2,3,4

save

rectng,4,22,4,8

aplot

aovlap,all !面搭接

adele,3

aplot

save

！划分网格

esize,1

amesh,5

mat,2

aplot

amesh,4

eplot

/pnum,elem

/number,1

save

！进入加载求解

/SOLU

antype,trans
！设定为瞬态分析

esel,s,mat,,2
！设定铸钢的初始温度

nsle,s

/replot

ic,all,temp,2875

esel,inve
！设定砂模的初始温度

nsle,s

/replot

ic,all,temp,80

allsel

save

lplot

sfl,1,CONV,0.014,,80
！设定砂模外边界对流

sfl,3,CONV,0.014,,80

sfl,4,CONV,0.014,,80

/psf,conv,2

time,3
！设定瞬态分析时间

kbc,1
！设定为阶越的载荷

autots,on
！打开自动时间步长

deltim,0.01,0.001,0.25
！设定时间步长

timint,on
！打开时间积分

tintp,,,,1
！将THETA设定为1

outres,all,all
！输入每个子步的结果

solve

！进入后处理

/post26

/pnum,node,1

/number,0

eplot

nsol,2,204,temp,center
！设定铸钢中心点温度随时间的变量

plvar,2
！绘制温度～时间曲线

save

finish