高手帮忙看一下错在哪里，实在没辙了，崩溃了

对你的命令流做了修改，计算成功：
! 修改处见标记 !**
finish
/clear
/filname, wenchao
/TITLE,wenchao !指定标题
/COM,Structural !选择分析类型为结构分析
/prep7
!建立第一榀关键点
k,1,0,0,0
k,2,5000,-555,0
k,3,5000,1696,0
k,4,10000,-890,0
k,5,10000,2678,0
k,6,15000,-1000,0
k,7,15000,3000,0
k,8,20000,-890,0
k,9,20000,2678,0
k,10,25000,-555,0
k,11,25000,1696,0
k,12,30000,0,0
!建立第一榀线
lstr,1,2
lstr,2,3
lstr,2,4
lstr,4,5
lstr,4,6
lstr,6,7
lstr,6,8
lstr,8,9
lstr,8,10
lstr,10,11
lstr,10,12
!整体复制偏移，建立第一、第三榀线和相应关键点
lgen,3,1,11,,0,0,-6000
!建立纵向梁
*do,i,1,11,2
lstr,i,i+12
lstr,i+12,i+24
*enddo
lstr,12,12+12
lstr,12+12,12+24
!建立屋面板
*do,i,1,9,2
l,i,i+2
*enddo
*do,i,25,33,2
l,i,i+2
*enddo
l,11,12
l,35,36
al,34,35,53,37,36,48
al,36,37,54,39,38,49
al,38,39,55,41,40,50
al,40,41,56,43,42,51
al,42,43,57,45,44,52
al,44,45,59,47,46,58
!截止
!索单元定义,仅受拉
et,1,link10
keyopt,1,2,2 !** 受压时纵向和横向都给以小刚度
keyopt,1,3,0
*SET,RCAB,5
r,1,3.14*RCAB*RCAB,0.005 !** 0.5 ! change to 0.005
!撑杆单元定义
et,2,link8
*SET,RCG,5
r,2,3.14*RCG*RCG
!梁单元定义
et,3,beam189
SECTYPE, 1, BEAM, CTUBE, section1, 3
SECOFFSET, CENT
SECDATA,40,45,8
!面板单元定义
et,4,shell63
r,4,2,2,2
!定义材料属性
MAT,1
MAT1=1
MP,DENS,MAT1,7.85e-9 !** not 7850e-6
MP,EX,MAT1,2.06E5 !定义弹性模量
MP,NUXY,MAT1,0.3 !定义泊松比
TB,BISO,MAT1,1,4 !定义双线性本构参数，温度为1
TBTEMP,1.0 !第一种温度下的数据
TBDATA,1,235,1000 !** not 2.35,1000 屈服应力及剪切模量
!划分索单元
lsel,s,line,,1,11,2
lsel,a,line,,12,22,2
lsel,a,line,,23,33,2
latt,1,1,1,
lesize,all,,,1
lmesh,all
!划分撑杆单元
lsel,none
*do,i,2,10,2
lsel,a,line,,i,i+22,11
*enddo
latt,1,2,2,
lesize,all,,,1
lmesh,all
!划分梁单元
lsel,s,line,,34,47,1
latt,1,,3,,,,1
lesize,all,,,10
lmesh,all
!划分壳单元
asel,s,,,1,6
aatt,1,4,4,
esize,all,10
mshape,0,2d
amesh,all
!约束底部关键点
dk,1,ux,0,0,0,uy,uz
dk,12,uy,0,0,0,uz,ux
dk,13,ux,0,0,0,uy,uz
dk,24,uy,0,0,0,uz,ux
dk,25,ux,0,0,0,uy,uz
dk,36,uy,0,0,0,uz,ux
allsel
!设置加速度 9800
acel,, 9800,,
finish
/solu
antype,static
!** 设置求解选项
OUTPR,BASIC,ALL,
/GST,1
!*
!*
OUTRES,ALL,ALL,
!*
TIME,1
AUTOTS,-1
DELTIM,0.01,1e-4,0.4,1
KBC,0
!*
TSRES,ERASE
!*
NLGEOM,1
NROPT,AUTO, ,
STAOPT,DEFA
LUMPM,0
EQSLV, , ,0,
PRECISION,0
MSAVE,0
PCGOPT,0, ,AUTO, , ,AUTO
PIVCHECK,1
SSTIF
PSTRES
TOFFST,0,
!*
SAVE
! solve
finish

请把你遇到的问题详细说明一下，如：分析什么问题，如何建模的，出现什么错误信息等。光是一个命令流很难分析。不过可以先给你提出一点问题：
1 看来你的长度单位使用的是 mm，那么材料密度应该是 7.85e-9，不是 7850e-6；相应的重力加速度应该是 9800；
2 你的材料应该是 钢，材料的屈服强度 2.35 (MPa) 太小了,改为 235 试试；
3 Link10 单元的初始应变 0.5 太大了，光是初应变就使 Link10 单元进入了塑性，实际情况不可能这样，请输入一个合适的初应变值，比如 0.005。(可以先不加重力算算看)
可能还有其它问题，自己再查查。
如仍解决不了，把问题发到 htbbzzg@163.com 帮你看看。