加载请教

在任意面施加任意方向任意变化的压力



　　在某些特殊的应用场合，可能需要在结构件的某个面上施加某个坐标方向的随坐标位置变化的压力载荷，当然，这在一定程度上可以通过ANSYS表面效应单元实现。如果利用ANSYS的参数化设计语言，也可以非常完美地实现此功能，下面通过一个小例子描述此方法。

!!!
!!!在执行如下加载命令之前,请务必用选择命令asel将需要加载的几何面选择出来
!!!
finish
/prep7
et,500,shell63
press=100e6
amesh,all
esla,s
nsla,s,1
! 如果载荷的反向是一个特殊坐标系的方向,可在此建立局部坐标系,并将
! 所有节点坐标系旋转到局部坐标系下.
*get,enmax,elem,,num,max !把当前选中的对象的最大单元号赋予enmax
dofsel,s,fx,fy,fz
fcum,add !!!将力的施加方式设置为"累加",而不是缺省的"替代"
*do,i,1,enmax
*if,esel(i),eq,1,then !i若在所选择单元中，esel（i）＝1，否则为0。
*get,ae,elem,i,area !此命令用单元真实面积，如用投影面积，请用下几条命令
! *get,ae,elem,i,aproj,x !此命令用单元X投影面积，
! *get,ae,elem,i,aproj,y !此命令用单元Y投影面积
! *get,ae,elem,i,aproj,z !此命令用单元Z投影面积
xe=centrx(i) !单元i中心X坐标(用于求解压力值)
ye=centry(i) !单元i中心Y坐标(用于求解压力值)
ze=centrz(i) !单元i中心Z坐标(用于求解压力值)
! 下面输入压力随坐标变化的公式,本例的压力随X和Y坐标线性变化.
p_e=(xe-10)*press+(ye-5)*press
f_tot=p_e*ae
esel,s,elem,,i
nsle,s,corner
*get,nn,node,,count
f_n=f_tot/nn
*do,j,1,nn
f,nelem(i,j),fx,f_n !压力的作用方向为X方向
! f,nelem(i,j),fy,f_n !压力的作用方向为Y方向
! f,nelem(i,j),fz,f_n !压力的作用方向为Z方向
*enddo
*endif
esla,s
*enddo
aclear,all
fcum,repl !!!将力的施加方式还原为缺省的"替代"
dofsel,all
allsel

分网后建立局部坐标系，将节点旋转入局部坐标系加载