桁架

DEFINE_zhongjianjie_6m
!初始化ansys环境
/PMACRO !将指定的宏内容写入到ANSYS会话LOG文件中
FINISH
/CLEAR !清除数据库，开始一个新的分析
/FILNAM,M_MODEL_6m !定义文件名，文件名为MODEL_6m
!定义几何模型参数
L1=6 !中间节臂长
L2=1.3000 !中间节臂宽
L3=1.3000 !中间节臂高
L4=0.1200 !中间节臂接头长
N=8 !中间斜腹管数
*dim,AA,,N !定义一个有N个元素的向量数组，数组名为AA
*do,i,1,N,1 !do循环，变量i，初值1，终值N，增量1
AA(i)=(L1-2*L4)/N !AA(i)代表的是相邻节点间的距离
*enddo !结束do循环
!定物理特性参数
D1=0.0760 !主弦杆外直径
T1=0.0055 !主弦杆管壁厚
D2=0.0420 !斜向腹杆外直径
T2=0.0030 !斜向腹杆管壁厚
D3=0.0420 !垂向腹杆外直径
T3=0.0030 !垂向腹杆管壁厚
!Define all paras 定义材料特性参数(全部长度单位米)
EX_1=2.1E11 !定义弹性模量值
PRXY_1=0.3 !主泊松比的值
DENS_1=8347 !质量密度值
FORCE=1000 !施加的力的值
/PREP7 !进入前处理器
!define element type 定义元素类型（95）和材料特性
ET,1,PIPE16 !定义单元类型，编号为1的pipe16，管模型用
ET,2,MASS21 !定义单元类型，编号为2的mass21，质量点用
!*
R,1,D1,T1,,,,, !定义单元实常数，第1组值D1、T1
RMORE,,,,,,, !添加实常数到一个常数集中。此命令在此可删除。
RMORE,,
!*
R,2,D2,T2,,,,, !定义单元实常数，第2组值D2、T2
RMORE,,,,,,, !添加实常数
RMORE,,
!*
R,3,D3,T3,,,,,
RMORE,,,,,,,
RMORE,,
!*
R,4,1.1*D1,2*T1,,,,, !定义单元实常数，第4组，值为1.1*D1、2*T1
RMORE,,,,,,,
RMORE,,
R,5,le-5,,,,,, !定义第5组单元实常数，值为le-5。
UIMP,1,EX,,,EX_1, !定义弹性模量值为EX-1所代表的值
UIMP,1,PRXY,,,PRXY_1, !主泊松比为PRXY-1所代表的值
UIMP,1,ALPX,,,, !输入一个常数值的热膨胀系数
UIMP,1,REFT,,,, !定义参考温度
UIMP,1,MU,,,, !定义摩擦因数
UIMP,1,DAMP,,,, !用于阻尼的K矩阵乘子
UIMP,1,DENS,,,DENS_1, !质量密度值为DENS-1所代表的值
!*
!----------------------以下建臂架----
!Begin to creat crank jab
!开始建立臂架
!
!Define KPoint 生成关键点
!画直线与镜像，拷贝
K,1,L2/2,L3/2,0, !KP1,主弦杆起点坐标点（L2/2,L3/2,0）
K,2,L2/2,L3/2,L1, !KP2,主弦杆终点坐标点（L2/2,L3/2,L）
LSTR,1,2 !生成第一根主弦杆
LSYMM,Y,ALL,,,,0,0 !镜像拷贝主弦管，关于Y轴对称，生成节点和控制键，同时保留原来关键点
LSYMM,X,ALL,,,,0,0 !镜像拷贝主弦管，关于X轴对称，生成节点和控制键，同时保留原来关键点
!-------------生成主弦杆----
KWPAVE,1 !移动工作平面到编号为1的关键点
wpoff,0,0,L4 !相对当前点移动工作平面，移动距离分别为0,0，L4
LSBW,all !用工作平面分割所有的线
*do,i,1,N,1 !进入do循环
wpoff,0,0,AA(i) !相对当前点移动工作平面，移动距离为0,0，AA（i）
LSBW,all !分割所有线
*enddo
!--------------生成第一组斜向腹杆----
WPCSYS,-1,0 !将工作平面与整体坐标相对应
LSTR,kp(L2/2,-L3/2,L4),kp(-L2/2,-L3/2,L4) !生成线，在此坐标下，生成的是垂线
LK=L4
wpoff,0,0,LK ! 相对当前点移动工作平面，移动距离为0,0，Lk
CSYS,4 !指定工作平面
*do,i,0,N-1,1
*if,i,eq,0,then !if循环，如果i=0，那么执行下一条语句
LSTR,kp(L2/2,-L3/2,0),kp(-L2/2,-L3/2,AA(1))
*else
wpoff,0,0,AA(i)
LSTR,kp((-1)**(i)*L2/2,-L3/2,0),kp((-1)**(i+1)*L2/2,-L3/2,AA(i+1))
*endif !结束if循环
*enddo
LSTR,kp(L2/2,-L3/2,AA(i+1)),kp(-L2/2,-L3/2,AA(i+1)) !生成线，也是垂线
!--------------生成第二组斜向腹杆----
WPCSYS,-1,0
LSTR,kp(L2/2,L3/2,L4),kp(-L2/2,L3/2,L4)
LK=L4
wpoff,0,0,LK
CSYS,4
*do,i,0,N-1,1
*if,i,eq,0,then
LSTR,kp(-L2/2,L3/2,0),kp(L2/2,L3/2,AA(1))
*else
wpoff,0,0,AA(i)
LSTR,kp((-1)**(i+1)*L2/2,L3/2,0),kp((-1)**(i)*L2/2,L3/2,AA(i+1))
*endif
*enddo
LSTR,kp(L2/2,L3/2,AA(i+1)),kp(-L2/2,L3/2,AA(i+1))
!---------------生成第三组斜向腹杆----
WPCSYS,-1,0
LSTR,kp(L2/2,L3/2,L4),kp(L2/2,-L3/2,L4)
LK=L4
wpoff,0,0,LK
CSYS,4
*do,i,0,N-1,1
*if,i,eq,0,then
LSTR,kp(L2/2,-L3/2,0),kp(L2/2,L3/2,AA(1))
*else
wpoff,0,0,AA(i)
LSTR,kp(L2/2,(-1)**(i+1)*L3/2,0),kp(L2/2,(-1)**(i)*L3/2,AA(i+1))
*endif
*enddo
LSTR,kp(L2/2,-L3/2,AA(i+1)),kp(L2/2,L3/2,AA(i+1))
!---------------生成第四组斜向腹杆----
WPCSYS,-1,0
LSTR,kp(-L2/2,L3/2,L4),kp(-L2/2,-L3/2,L4)
LK=L4
wpoff,0,0,LK
CSYS,4
*do,i,0,N-1,1
*if,i,eq,0,then
LSTR,kp(-L2/2,L3/2,0),kp(-L2/2,-L3/2,AA(1))
*else
wpoff,0,0,AA(i)
LSTR,kp(-L2/2,(-1)**(i)*L3/2,0),kp(-L2/2,(-1)**(i+1)*L3/2,AA(i+1))
*endif
*enddo
LSTR,kp(-L2/2,-L3/2,AA(i+1)),kp(-L2/2,L3/2,AA(i+1))
!---------------生成两断面斜向腹杆----
WPCSYS,-1,0
LSTR,kp(-L2/2,-L3/2,L4),kp(L2/2,L3/2,L4)
line_11=_return !返回这条线的编号
LSTR,kp(L2/2,-L3/2,L1-L4),kp(-L2/2,L3/2,L1-L4)
line_12=_return
!---------------定义斜向腹杆属性----
CSYS,0 !指定直角坐标系
LPLOT !显示线
ALLSEL,ALL !选择所有实体
LSEL,S,LOC,Y,-0.5*L3/2,0.5*L3/2 !选择有效线段，从数据集中选择，Y坐标介于-0.5*L3/2至0.5*L3/2
LSEL,A,LOC,X,-0.5*L2/2,0.5*L2/2 !选择有效线段，从数据集中再选择部分数据添加到选择集中，X坐标介于-0.5*L2/2至0.5*L2/2

ALLSEL,BELOW,LINE !选择直接相关的线实体
!*
LATT,1,2,1,,,, ! 定义各种元素类型
!---------------定义主弦杆属性----
CM,FUGAN,LINE !由所选择的实体生成一个实体，线实体名为FUGAN
ALLSEL,ALL
CMSEL,U,FUGAN !选择从整体中减去ＦＵＧＡＮ的剩余部分实体
LATT,1,1,1,,,,
ALLSEL,ALL　　　　!选择所有实体
LPLOT　　　　　　!显示线
!---------------定义垂向腹杆属性----
ALLSEL,ALL
LPLOT
LSEL,S,LOC,Z,L4　　　　!从实数集中选择Ｚ坐标为Ｌ４的有效线段
LSEL,A,LOC,Z,L1-L4 !
LSEL,U,,,line_11　　!从所选择线中减去line_11所代表的线
LSEL,U,,,line_12　　!从所选择线中减去line_12所代表的线
ALLSEL,BELOW,LINE!*
LATT,1,3,1,,,,
ALLSEL,ALL
!-------定义接头属性----
ALLSEL,ALL
LPLOT
LSEL,S,LOC,Z,0,L4
LSEL,A,LOC,Z,L1-L4,L1
LSEL,U,LOC,Z,L4
LSEL,U,LOC,Z,L1-L4
ALLSEL,BELOW,LINE
!*
LATT,1,4,1,,,,
ALLSEL,ALL
!---------------画网格----
ALLSEL,ALL
ESIZE,5*D1,0, !定义要划分的单元边长和分段数，单元边数为5*D1，段数为0

LMESH,ALL !网格化所有实体
/ESHAPE,1.0 !根据实常数1.0来确定单元的显示
NUMMRG,ALL,,,,LOW !合并所有实体，保留低编号项
/REPLOT !刷新显示实体
ALLSEL,ALL
SAVE,, !保存
CDWRITE,ALL,,'cdb',,,'iges' !写模型